One ring to rule them all: How UK and Australia relations with China react to US-China shocks

One ring to rule them all, one ring to find them, One ring to bring them all, and in the darkness bind them; In the Land of Mordor where the shadows lie.

The Hobbit (1937) . J.R.R. Tolkien.

In this blog, I will update a previous one on Geopolitics, Strategic Alliances and Granger Causality. Besides, we are going to how UK and Australia relations with China react to US-China shocks, using the Local Projection methods and cumulated differences (long-differenced) as recommended by Pilger and Stockwell (2025).

Key takeaways:

Relationships with China knew contrasting evolutions over the last years (2022-2024).
The relation of China with Australia clearly improved.
The relationships of China with South Korea and, in a more striking way, with India have known a recent deterioration.
An improvement of US-China relationship causes an improvement of relations of the UK and Australia with China, revealing an alliance behavior.
The most recent data show an alliance behavior between US, the UK, and Australia that precedes the recent creation of the AUKUS military alliance.

The updated data show that the relationships with China knew contrasting evolutions over the last years (2022-2024). The relations of China with France and Germany have experienced some stabilization. The relationships of China with Japan and the US have known modest improvements. The relation of China with Australia clearly improved.

The relations of China with its partners in Asia with Russia and with Pakistan are good and stable. For Vietnam and Indonesia, the relations with China slightly improved over recent years (2022-2024). The relationships of China with South Korea and, in a more striking way, with India have known a recent deterioration. The recent fears of a water war about the Bramhaputra river being a prime example of these tensions between India and China.

The VAR(7) is stable so I use the Local Projection method with 7 lags to assess the impact of exogenous improvement of the relation between US and China on (a) the relation between UK and China and (b) the relation between Australia and China, using long-difference as recommended by Pilger and Stockwell (2025). An improvement of US-China relationship causes an improvement of relations of the UK and Australia with China, revealing an alliance behavior.

I also check the reverse causality to see the reaction of US-China relations after an increase in UK-China relations and Australia-China relations. No reverse causality here.

The code is explained below:

import excel "C:\Users\jamel\Dropbox\Latex\PROJECTS\25-08-oil-pri-iv\Dataset.xlsx", sheet("Feuil1") firstrow clear

generate Period = tm(1950m1) + _n-1
format %tm Period

tsset Period

keep if Period>=tm(1990m1)

set varabbrev off

foreach v in JPN AUS FRA GER UK USA ///
 INDO PAK RUS VN INDIA CDS{
 	/* Another transformation for the PRI index */
    gen L`v' = sign(`v') * log(1 + abs(`v'))
	gen DL`v' = d.L`v'
 }

**# Non-allies of China 
 
set scheme white_tableau 

// 1) Last nonmissing value for each series
foreach v in LJPN LAUS LFRA LGER LUK LUSA {
    quietly summarize Period if !missing(`v'), meanonly
    local t_`v' = r(max)
    quietly summarize `v' if Period==`t_`v'', meanonly
    local val_`v' = r(mean)
}

// 2) Build legend order (descending by last value) — FIXED MATA
mata:
    vals = ( `val_LJPN' \ `val_LAUS' \ `val_LFRA' \ `val_LGER' \ `val_LUK' \ `val_LUSA' )
    idx  = ( 1 \ 2 \ 3 \ 4 \ 5 \ 6 )
    ord = order(-vals,1)
    idx_ord = idx[ord]
    st_local("legend_nums", invtokens(strofreal(idx_ord')))
end

// 3) Plot with dynamic legend order and readable labels
tsline LJPN LAUS LFRA LGER LUK LUSA, ///
    legend(order(`legend_nums') pos(2) col(1) size(2.5) ///
           label(1 "Japan") ///
           label(2 "Australia") ///
           label(3 "France") ///
           label(4 "Germany") ///
           label(5 "United Kingdom") ///
           label(6 "United States")) ///
    name(PRIg1, replace) xti("") yline(0) ///
	ti("Relations with China (Log-modulus transform)", ///
	size(small))

**# Allies of China

// 1) Last nonmissing value for each series
foreach v in LINDO LPAK LRUS LVN LINDIA LCDS {
    quietly summarize Period if !missing(`v'), meanonly
    local t_`v' = r(max)
    quietly summarize `v' if Period==`t_`v'', meanonly
    local val_`v' = r(mean)
}

// 2) Build legend order (descending by last value) — Mata
mata:
    vals = ( ///
        `val_LINDO' \ ///
        `val_LPAK'  \ ///
        `val_LRUS'  \ ///
        `val_LVN'   \ ///
        `val_LINDIA'\ ///
        `val_LCDS' )
    idx  = (1 \ 2 \ 3 \ 4 \ 5 \ 6)
    ord = order(-vals,1)
    idx_ord = idx[ord]
    st_local("legend_nums", invtokens(strofreal(idx_ord')))
end

// 3) Plot with dynamic legend order and readable labels
tsline LINDO LPAK LRUS LVN LINDIA LCDS, ///
    legend(order(`legend_nums') pos(2) col(1) size(2.5) ///
           label(1 "Indonesia") ///
           label(2 "Pakistan")  ///
           label(3 "Russia")    ///
           label(4 "Vietnam")   ///
           label(5 "India")     ///
           label(6 "South Korea"))     ///
    name(PRIg2, replace) xti("") yline(0) ///
	ti("Relations with China (Log-modulus transform)", ///
	size(small))

*varsoc dlpri dlpri_jp dlpri_aus dlpri_cds dlpri_fra dlpri_ger dlpri_india dlpri_indo dlpri_pak dlpri_rus dlpri_vn dlpri_uk, max(2)

var DLJPN DLAUS DLFRA DLGER DLUK DLUSA DLINDO DLPAK ///
 DLRUS DLVN DLINDIA DLCDS, lag(7)

varstable, ///
 graph name(stable, replace)
 
vargranger

tsline LUSA LAUS LUK LCDS, ///
 legend(size(2.5)) name(PRIg3, replace) ///
 xti("") yline(0) leg(pos(2) col(1) size(2.5))
 
tsline LRUS LINDO LINDIA LVN, ///
 legend(size(2.5)) name(PRIg4, replace) ///
 xti("") yline(0) leg(pos(2) col(1) size(2.5))

// Local Projection Alliances 
 
locproj LUK, shock(LUSA) ///
 z h(-12/48) yl(6) sl(7) r tr(cmlt) ///
 noisily stats ///
 save irfn(USUK) grname(LP_USUK)
 
locproj LAUS, shock(LUSA) ///
 z h(-12/48) yl(6) sl(7) r tr(cmlt) ///
 noisily stats ///
 save irfn(AUSUK) grname(LP_AUSUK)
 
lpgraph USUK AUSUK, h(-12/48) tti(Months) ///
 tti(Months) ///
 lc1(green) lc2(blue) z grname(LP_blog) ///
  lab1(UK-China relations) lab2(Australia-China relations) ///
 grsave(LP_blog) as(png) ///
 ti("Diplomatic relations with China after an increase of US-China relations", size(small)) 
graph export LP_blog.png, as(png) width(4000) replace

locproj LUSA, shock(LUK) ///
 z h(-12/48) yl(6) sl(7) r tr(cmlt) ///
 noisily stats ///
 save irfn(UKUS) grname(LP_UKUS)
 
locproj LUSA, shock(LAUS) ///
 z h(-12/48) yl(6) sl(7) r tr(cmlt) ///
 noisily stats ///
 save irfn(UKAUS) grname(LP_UKAUS)

lpgraph UKUS UKAUS, h(-12/48) tti(Months) ///
 tti(Months) ///
 lc1(green) lc2(blue) z grname(LP_blog2) ///
  lab1(US-China relations (UK)) ///
  lab2(US-China relations (AUS)) ///
 grsave(LP_blog2) as(png) ///
 ti("Reverse causality", size(small)) 
graph export LP_blog2.png, as(png) width(4000) replace

Conclusion

As we have seen in this blog, we are living in world with military and diplomatic alliances. The most recent data show an alliance behavior between US, the UK, and Australia that precedes the recent creation of the AUKUS military alliance.

Is your PhD thesis still relevant today?