Working papers


Unpublished manuscripts and supplementary files (graphs, data and codes) can be found on this page.


Unpublished manuscripts


Amélie Barbier-Gauchard, Meixing Dai, Claire Mainguy, Jamel Saadaoui, Moïse Sidiropoulos, Isabelle Terraz and Jamel Trabelsi. Towards a more resilient European Union after the COVID-19 crisis. BETA Working Paper 2020-33 (2020). Available at SSRN: https://ssrn.com/abstract=3641306

Abstract
The pandemic crisis constitutes an unprecedented challenge for the European Union and for the Euro Area. Indeed, European institutional architecture can be viewed as being half-way between an association of sovereign states (like the United Nations, for example) and a politically integrated federation (like the United States for example). In this original construction, competences on several matters (such as economic, political, social and health issues, etc.) are shared at the European level, but also at the national and local levels in more complex ways than in fully integrated federations. To improve the resilience of the European Union to violent external shocks, the main objective of this paper is to determine to what extent these competences have to be transferred to the federal level. In this respect, we will consider whether a federal leap is necessary in several areas namely (i) monetary and fiscal policy (rules), (ii) labor markets policy and social models, migratory flows and skill shortages, and cooperation policy and (iii) renewed industrial policy and exchange rates. Despite a highly uncertain context, we outline some perspectives for the future of the European Union.

Keywords: European Union, Pandemic Crisis, Economic Policy, Resilience

JEL Classification: F33, E52, E62, F22, J61, L52


Sy-Hoa Ho, Jamel Saadaoui.
Symmetric and Asymmetric Effects of Exchange Rates on Money Demand: Empirical Evidence From Vietnam. SSRN working paper 3507120 (2019): https://dx.doi.org/10.2139/ssrn.3507120.

Abstract
This empirical investigation aims at exploring the determinants of money demand in Vietnam by using both linear and nonlinear autoregressive distributed lags models over the period spanning from the third quarter of 2000 to the first quarter of 2018. Our findings can be summarized as follows: firstly, when the shock is symmetric (i.e. a permanent nominal appreciation of one percent), the money demand increases by 3.7 percent in the long term. Secondly, when the shock is asymmetric, for a permanent nominal appreciation of one percent, we observe an increase of 15.6 percent in the money demand. Whereas, for a permanent nominal depreciation of one percent, we observe a decrease of 7.4 percent in the money demand. These results are consistent with symmetry tests and lead us to think that asymmetries occur mainly in the short run and are transmitted to the long run.

Keywords: Money Demand, Exchange Rate, ARDL models, NARDL models, Dollarization

JEL Classification: C22, E41, F31, F33 , F41


STATA Codes


Stata code for replicate the results of the following article :

Jamel Saadaoui.
Global imbalances: Should we use fundamental equilibrium exchange rates? Economic Modelling 47, pp. 383-3982015. DOI: 10.1016/j.econmod.2015.02.007.

The following datatset has been used in this study :

* Co-integration analysis for XR dynamics
*----------------------------------------

version 15.1
set more off
cd "C:\..."	// Set the directory
capture log close
log using xrdynamics.smcl, replace

clear

*Import the data from Excel

import ///
excel "C:\...\EXCEL-2015.xlsx", ///
sheet("data_fin") firstrow // Note 1

*Install User-Written Stata Programs

capture ssc install pescadf // Note 2
capture ssc install xtwest
capture ssc install xtpmg
capture ssc install xtmg
capture ssc install ltimbimata
capture ssc install xtdolshm
capture ssc install outreg2

*Generate variable in logarithm

generate logreer = ln(reer)
generate logfeer = ln(feer)
generate logreer_cs = ln(reer_cs)
generate logfeer_cs = ln(feer_cs)

*Panel setting (N=26; T=29; N*T=754)

xtset country period, yearly

*UNIT ROOT TEST
*CADF test (Pesaran, 2007)

pescadf  logfeer, lags(1) trend
pescadf  logreer, lags(1) trend
pescadf  d.logfeer, lags(1) trend
pescadf  d.logreer, lags(1) trend

*COINTEGRATION TESTS
*Persyn & Westerlund (2008)

xtwest logreer logfeer, lags (0 2) 
xtwest logfeer logreer, lags (0 2)

set matsize 800

xtwest logreer logfeer, lags (0 2) bootstrap(100)
xtwest logfeer logreer, lags (0 2) bootstrap(100)

*ESTIMATION OF THE ERROR-CORRECTION MODEL THANKS TO
*THE PMG (CPMG) ESTIMATOR
*PESARAN et al. (1999)

xtpmg d.logreer d.logfeer, ///
lr(l.logreer logfeer) ec(ec) replace pmg

outreg2 using results_pmg_1, ///
excel pvalue replace ///
cttop(D.logreer) addnote(Notes:) // Note 2

*dmg = dynamic mg estimator

xtpmg d.logreer d.logfeer, ///
lr(l.logreer logfeer) ec(ec) replace mg

outreg2 using results_dmg_1, excel ///
pvalue replace cttop(D.logreer) addnote(Notes:)

hausman mg pmg, sigmamore

xtpmg d.logfeer d.logreer, ///
lr(l.logfeer logreer) ec(ec) replace pmg

outreg2 using results_pmg_2, /// 
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

*dmg = dynamic mg estimator

xtpmg d.logfeer d.logreer, ///
lr(l.logfeer logreer) ec(ec) replace mg

outreg2 using results_dmg_2, ///
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

hausman mg pmg, sigmamore

xtpmg d.logreer d.logfeer d.logreer_cs d.logfeer_cs, /// 
lr(l.logreer logfeer l.logreer_cs logfeer_cs) ///
ec(ec) replace pmg

outreg2 using results_cpmg_1, ///
excel pvalue replace ///
cttop(D.logreer) addnote(Notes:)

xtpmg d.logreer d.logfeer d.logreer_cs d.logfeer_cs, ///
lr(l.logreer logfeer l.logreer_cs logfeer_cs) ///
ec(ec) replace mg

outreg2 using results_cdmg_1, ///
excel pvalue replace ///
cttop(D.logreer) addnote(Notes:)

hausman mg pmg, sigmamore

xtpmg d.logfeer d.logreer d.logfeer_cs d.logreer_cs, ///
lr(l.logfeer logreer l.logfeer_cs logreer_cs) ///
ec(ec) replace pmg

outreg2 using results_cpmg_2, ///
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

xtpmg d.logfeer d.logreer d.logfeer_cs d.logreer_cs, ///
lr(l.logfeer logreer l.logfeer_cs logreer_cs) ///
ec(ec) replace mg

outreg2 using results_cdmg_2, ///
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

hausman mg pmg, sigmamore

*STUDY SHORT RUN DYNAMICS

xtpmg d.logreer d.logfeer, ///
lr(l.logreer logfeer) ec(ec) replace pmg full

outreg2 using results_pmg_1_SR, ///
excel pvalue replace ///
cttop(D.logreer) addnote(Notes:)

xtpmg d.logfeer d.logreer, ///
lr(l.logfeer logreer) ec(ec) replace pmg full

outreg2 using results_pmg_2_SR, ///
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

xtpmg d.logreer d.logfeer d.logreer_cs d.logfeer_cs, ///
lr(l.logreer logfeer l.logreer_cs logfeer_cs) ///
ec(ec) replace pmg full

outreg2 using results_cpmg_1_SR, ///
excel pvalue replace ///
cttop(D.logreer) addnote(Notes:)

xtpmg d.logfeer d.logreer d.logfeer_cs d.logreer_cs, ///
lr(l.logfeer logreer l.logfeer_cs logreer_cs) ///
ec(ec) replace pmg full

outreg2 using results_cpmg_2_SR, ///
excel pvalue replace ///
cttop(D.logfeer) addnote(Notes:)

*PESARAN (2006) COMMON CORRELATED EFFECTS 
*MEAN GROUP ESTIMATOR

xtmg logreer logfeer, cce robust

outreg2 using results_ccemg_1, /// 
excel pvalue replace ///
cttop() addnote(Notes:)

xtmg logfeer logreer, ///
cce robust

outreg2 using results_ccemg_2, ///
excel pvalue replace ///
cttop() addnote(Notes:)

*PESARAN & SMITH (1995) 
*MEAN GROUP ESTIMATOR

xtmg logreer logfeer, robust

outreg2 using results_smg_1, ///
excel pvalue replace ///
cttop() addnote(Notes:)

*smg = static mg estimator

xtmg logfeer logreer, robust

outreg2 using results_smg_2, ///
excel pvalue replace ///
cttop() addnote(Notes:)

*KAO & CHIANG (2000) DOLS ESTIMATOR

xtdolshm logreer logfeer, nla(2) nle(2)
outreg2 using results_dols_1, ///
excel pvalue replace ///
cttop() addnote(Notes:)

xtdolshm logfeer logreer, nla(2) nle(2)
outreg2 using results_dols_2, ///
excel pvalue replace ///
cttop() addnote(Notes:)

// Save the data
save ///
"C:\...\xrdynamics.dta", ///
replace

log close
exit

Description
-----------

This file aims at analyzing the long run relationship
between actual REERs and equilibrium REERs. The equilibrium 
rates are obtained  thanks to a FEER approach.

Notes :
-------

1) Replace the "..." by the path of the current directory.
2) We use the capture command to override message when 
   variables are already generated or packages already 
   installed.
3) With the Excel option of the STATA command outreg2, I
   recommend using the useful package excel2latex.

Nota bene: I am grateful to Roy Wada, Markus Eberhardt, Damiaan Persyn, Edward F. Blackburne III, Mark W. Frank, Piotr Lewandowski and Ibrahima Amadou Diallo for making publicly available their STATA codes.